stmt\_list : (stmt)\*

stmt : data\_type ID decl\_suffix?

| VOID\_TYPE ID LPAREN formal\_args? RPAREN stmt

| ID id\_suffix

| OUT exp

| RETURN exp?

| WHILE exp stmt

| IF exp stmt (ELSE stmt)?

| FOR (INT\_TYPE? ID ASSIGN)? exp COLON exp COLON exp stmt

| stmt\_list

data\_type : BOOL\_TYPE ARR\_TYPE?

| INT\_TYPE ARR\_TYPE?

| FLOAT\_TYPE ARR\_TYPE?

| FRACT\_TYPE ARR\_TYPE?

| STRING\_TYPE ARR\_TYPE?

decl\_suffix : LPAREN formal\_args? RPAREN stmt

| ASSIGN exp

id\_suffix : LPAREN actual\_args? RPAREN (LBRACKET exp RBRACKET ASSIGN exp)?

| LBRACKET exp RBRACKET (LPAREN actual\_args? RPAREN)?

| ASSIGN exp

exp : exp\_low

exp\_low : exp\_med ((EQ|LE) exp\_med)\*

exp\_med : exp\_high ((PLUS|MINUS) exp\_high)\*

exp\_high : primary ((MUL|DIV) primary)\*

primary : BOOL

| INT

| FLOAT

| FRACT

| STRING

| ID (LPAREN actual\_args? RPAREN)?

| LPAREN exp RPAREN

| MINUS primary

| NOT primary

| INPUT STRING?

| LBRACKET (exp (COMMA exp)\*)? RBRACKET

formal\_args : data\_type ID (COMMA data\_type ID)\*

actual\_args : exp (COMMA exp)\*

ID : <any valid variable name>

BOOL : True | False

INT : <any valid int number>

FLOAT : <any valid floating point number>

FRACT : <any valid fractional number>

STRING : <any valid quoted str constant>